OkuboTank tank;
Bug[] bugs;
int N = 300;
float timestep = 0.01;
toolbar sliders;
slider omegaSlider, betaSlider, BSlider, persistenceSlider;
color bkgndColor, textColor;
String creditsString;

color warmGrayColor = color(205,205,185);
color ltBlueColor = color(194,216,236);
color blueColor = color(0,80,160);
color orangeColor = color(220,50,7);


void setup() {
  size(800,500);
  smooth();
  textFont(createFont("LinotypeProjekt-Bold-12.vlw",12));
  
  float sz = min(width,height);
  float tankHalfWidth = 25;
  tank = new OkuboTank(0,0,0,sz,sz,sz);
  tank.modelMin = new vector(-tankHalfWidth,-tankHalfWidth,-tankHalfWidth);
  tank.modelMax = new vector(tankHalfWidth,tankHalfWidth,tankHalfWidth);
  
  bugs = new Bug[N];
  for (int i=0; i<N; i++) {
    bugs[i] = new OkuboBug(tank);
  }
  
  textColor = darken(darken(blueColor));
  sliders = new toolbar(new float[] {20, 20, width-50, 30}, 100);
  color neutralColor = textColor;
  color activeColor = darken(textColor);
  omegaSlider = sliders.addSlider("attraction to center","right",neutralColor,activeColor,0,4);
  BSlider = sliders.addSlider("excitation","below",neutralColor,activeColor,0,16);
  betaSlider = sliders.addSlider("damping","below",neutralColor,activeColor,0,4);
  persistenceSlider = sliders.addSlider("trail persistence","below",lighten(neutralColor),lighten(activeColor),0,100);
  persistenceSlider.setVal(50);

  // Daphnia initial values  
//  omegaSlider.setVal(0.49);
//  BSlider.setVal(3.6);
//  betaSlider.setVal(0.54);
  // Temora initial values
  omegaSlider.setVal(0.63);
  BSlider.setVal(13.3);
  betaSlider.setVal(0.80);
  
  bkgndColor = warmGrayColor;
  background(bkgndColor);
  
  creditsString = "the Okubo (1986) swarming model: for details, see\n\nNS Banas, J Yen, and D-P Wang (2003), ";
  creditsString += "''Experimental validation of an individual-based model for zooplankton swarming'' ";
  creditsString += "(Handbook of Scaling Methods in Aquatic Biology, Seuront & Strutton, eds., CRC Press)";
  creditsString += "\n\nvisualization by Neil Banas (neil@ocean.washington.edu)";
}



void draw() {
  noStroke();
  float a = 255 - 2.55*persistenceSlider.getVal();
  fill(red(bkgndColor),green(bkgndColor),blue(bkgndColor),a);
  rect(tank.origin.x, tank.origin.z, tank.span.x, tank.span.z);
  fill(bkgndColor);
  rect(tank.origin.x+tank.span.x, 0, width, height);
  
  timestep = 1/frameRate;
  for (int i=0; i<N; i++) {
    ((OkuboBug) bugs[i]).omega = omegaSlider.getVal();
    ((OkuboBug) bugs[i]).beta = betaSlider.getVal();
    ((OkuboBug) bugs[i]).B = BSlider.getVal();
    bugs[i].update(timestep);
  }

  tank.laserWidth = omegaSlider.getVal()/100;
  tank.draw();
    
  sliders.update();
  
  textAlign(RIGHT);
  textLeading(16);
  fill(textColor);
  text(creditsString, height, height-16*10, width-height-10, height);
}


void mousePressed() {
  sliders.offerMousePress();
}





void textSize(float n) {
  super.textSize(12);
}


float randn() {
  return sqrt(-2*log(random(1)))*cos(TWO_PI*random(1));
}